Sveiki, mačiau bent pora prašymų parašyti pamoką apie vartus su klavišo paspaudimu.

Šioje pamokoje aprašysiu du dalykus:

• Elementarus kodas vartams
• Paprastesnsi kodas turint daugiau nei vieną porą vartų

Elementarus kodas vartams

Šiame pavyzdyje kursime "labirinto" vartus atidaromus su mygtuku SPACE. Ko mums reikės?

• Uždarytų vartų koordinačių
• Atidarytų vartų koordinačių
• Dviejų kintamųjų

Pradėsim nuo kintamųjų:

new LabirintoVartuObjektas, bool:LabirintoVartaiUzdaryti = true;

Tarkime kad mano koordinatės:

Uždaryti:   1240.0, 500.0, 14.0, 0.0, 0.0, 0.0
Atidaryti:  1240.0, 500.0, 20.0, 0.0, 0.0, 90.0

Kaip matote, mano vartai pakils aukštyn ir pasisuks Z ašyje.

Sukurkime objektą. Pagalvokite ar norite kad vartai būtų uždaryti ar ne, atitinkamai rinkites ir koordinates:

public OnGameModeInit()
{
    LabirintoVartuObjektas = Createobject(objekto_modelis, 1240.0, 500.0, 14.0, 0.0, 0.0, 0.0);
    return 1;
}

Na iki dabar buvo vaikų žaidimai, pereinam prie atidarymo/uždarymo su mygtuku.

public OnPlayerKeyStateChange(playerid, newkeys, oldkeys)
{
    // Patikriname ar buvo nuspaustas ir atleistas mygtukas.
    // KEY_SPRINT paprastai būna tarpas.
    if((newkeys & KEY_SPRINT) && !(oldkeys & KEY_SPRINT))
    { 
        // Čia koordinatės kur žaidėjas turi būti kad veiktų vartai. Pas mane, jos sutampa su uždarytų vartų pozicijoa.
        if(IsPlayerInRangeOfPoint(playerid, 5.0, 1240.0, 500.0, 14.0))
        {
            if(LabirintoVartaiUzdaryti)
                MoveObject(LabirintoVartuObjektas, 1240.0, 500.0, 20.0, 1.0, 0.0, 0.0, 90.0);
            else
                MoveObject(LabirintoVartuObjektas, 1240.0, 500.0, 14.0, 1.0, 0.0, 0.0, 0.0);

            // Ši eilutė nustatys LabirintoVartaiUzdaryti reikšmę į priešingą. Jeigu buvo true, bus false. Jei buvo false, bus true.
            LabirintoVartaiUzdaryti = !LabirintoVartaiUzdaryti;
            return 1;
        }
    }
    return 1;
}

MoveObject naudojimas

Paprastesnsi kodas turint daugiau nei vieną porą vartų

Pažiūrėjus į praeitą kodą jis neatrodo ilgas. Bet jei turime 50 vartų? Ar norite tą patį rašyti 50 kartų?

Todėl siūlau susidėti visas koordinates į masyvą!

enum E_VARTU_DUOMENYS 
{
    Objektas,
    bool:Uzdaryti,
    Float:JudejimoGreitis,
    Float:AtidarytuX,
    Float:AtidarytuY,
    Float:AtidarytuZ,
    Float:AtidarytuRX,
    Float:AtidarytuRY,
    Float:AtidarytuRZ,
    Float:UzdarytuX,
    Float:UzdarytuY,
    Float:UzdarytuZ,
    Float:UzdarytuRX,
    Float:UzdarytuRY,
    Float:UzdarytuRZ,
};

new const VartuDuomenys[][ E_VARTU_DUOMENYS ] = 
{
    {1243, true, 1.0, 1240.0, 500.0, 14.0, 0.0, 0.0, 0.0, 1240.0, 500.0, 20.0, 0.0, 0.0, 90.0},
    {kiti vartai....}
};
new VartuObjektuID[ sizeof(VartuDuomenys) ],
    bool:VartaiUzdaryti[ sizeof(VartuDuomenys ]) ];

Jau dabar galima matyti keletą privalumų. Pavyzdžiui kad visi vartų duomenys bus vienoje vietoje.

public OnGameModeInit()
{
    for(new i = 0; i < sizeof(VartuDuomenys); i++)
    {
        if(VartuDuomenys[ i ][ Uzdaryti ])
        {
            VartuObjektuID[ i ] = CreateObject(VartuDuomenys[ i ][ Objektas ], VartuDuomenys[ i ][ UzdarytuX ], VartuDuomenys[ i ][ UzdarytuY ], VartuDuomenys[ i ][ UzdarytuZ ], VartuDuomenys[ i ][ UzdarytuRX ], VartuDuomenys[ i ][ UzdarytuRY ], VartuDuomenys[ i ][ UzdarytuRZ ]);
            VartaiUzdaryti[ i ] = true;
        }
        else 
        {
            VartuObjektuID[ i ] = CreateObject(VartuDuomenys[ i ][ Objektas ], VartuDuomenys[ i ][ AtidarytuX ], VartuDuomenys[ i ][ AtidarytuY ], VartuDuomenys[ i ][ AtidarytuZ ], VartuDuomenys[ i ][ AtidarytuRX ], VartuDuomenys[ i ][ AtidarytuRY ], VartuDuomenys[ i ][ AtidarytuRZ ]);
            VartaiUzdaryti[ i ] = false;
        }
    }
    return 1;
}

Objektų sukūrimas irgi šiek tiek pailgėjo, tačiau kad ir kiek bus vartų, šitas kodas nebesikeis. Pereinam prie atidarymo/uždarymo:

public OnPlayerKeyStateChange(playerid, newkeys, oldkeys)
{
    if((newkeys & KEY_SPRINT) && !(oldkeys & KEY_SPRINT))
    {
        for(new i = 0; i < sizeof(VartuDuomenys); i++)
        {
            if(IsPlayerInRangeOfPoint(playerid, 5.0, VartuDuomenys[ i ][ UzdarytuX ], VartuDuomenys[ i ][ UzdarytuY ], VartuDuomenys[ i ][ UzdarytuZ ]))
            {
                if(VartaiUzdaryti[ i ])
                    MoveObject(VartuObjektuID[ i ], VartuDuomenys[ i ][ AtidarytuX ], VartuDuomenys[ i ][ AtidarytuY ], VartuDuomenys[ i ][ AtidarytuZ ], VartuDuomenys[ i ][ JudejimoGreitis ], VartuDuomenys[ i ][ AtidarytuRX ], VartuDuomenys[ i ][ AtidarytuRY ], VartuDuomenys[ i ][ AtidarytuRZ ]);
                else 
                    MoveObject(VartuObjektuID[ i ], VartuDuomenys[ i ][ UzdarytuX ], VartuDuomenys[ i ][ UzdarytuY ], VartuDuomenys[ i ][ UzdarytuZ ], VartuDuomenys[ i ][ JudejimoGreitis ] VartuDuomenys[ i ][ UzdarytuRX ], VartuDuomenys[ i ][ UzdarytuRY ], VartuDuomenys[ i ][ UzdarytuRZ ]);
                VartaiUzdaryti[ i ] = !VartaiUzdaryti[ i ];
            }

        }
    }
    return 1;
}

Ir viskas! Vienintelis kodas kurį reikės keisti pridedant vartus tai tik masyvas su jų duomenimis.

Štai pamoka ir baigta. Žinoma mygtukus, atstumas, greičius, koordinates keiskite pagal savo norus :)